actions.precombat+=/battle_stance
actions.precombat+=/battle_shout
actions.precombat+=/use_item,name=algethar_puzzle_box

actions+=/charge,if=time<=0.5|movement.distance>8
actions+=/pummel
actions+=/spell_reflection
actions+=/potion,if=gcd.remains=0&debuff.colossus_smash.remains>8|boss&fight_remains<25
actions+=/algethar_puzzle_box,if=cooldown.avatar.remains<3
actions+=/vial_of_animated_blood,if=buff.avatar.up
actions+=/elementium_pocket_anvil,use_off_gcd=1
actions+=/beacon_to_the_beyond,use_off_gcd=1
actions+=/irideus_fragment,if=buff.avatar.up
actions+=/manic_grieftorch,if=!buff.avatar.up&!debuff.colossus_smash.up
actions+=/gladiators_badge,if=gcd.remains=0&debuff.colossus_smash.remains>8|boss&fight_remains<25
actions+=/use_items
actions+=/arcane_torrent,if=cooldown.mortal_strike.remains>1.5&rage<50
actions+=/lights_judgment,if=debuff.colossus_smash.down&cooldown.mortal_strike.remains
actions+=/bag_of_tricks,if=debuff.colossus_smash.down&cooldown.mortal_strike.remains
actions+=/berserking,if=debuff.colossus_smash.remains>6
actions+=/ancestral_call,if=debuff.colossus_smash.up
actions+=/blood_fury,if=debuff.colossus_smash.up
actions+=/ancestral_call,if=debuff.colossus_smash.up
actions+=/run_action_list,name=hac,strict=1,if=raid_event.adds.exists|active_enemies>2
actions+=/call_action_list,name=execute,cycle_targets=1,strict=1,if=(talent.massacre.enabled&target.health.pct<35)|target.health.pct<20
actions+=/run_action_list,name=single_target,strict=1,if=!raid_event.adds.exists

actions.execute+=/sweeping_strikes,if=spell_targets.whirlwind>1
actions.execute+=/rend,if=remains<=gcd&(!talent.warbreaker&cooldown.colossus_smash.remains<4|talent.warbreaker&cooldown.warbreaker.remains<4)&target.time_to_die>12
actions.execute+=/avatar,if=cooldown.colossus_smash.ready|debuff.colossus_smash.up|boss&fight_remains<20
actions.execute+=/warbreaker
actions.execute+=/colossus_smash
actions.execute+=/thunderous_roar,if=buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up
actions.execute+=/spear_of_bastion,if=debuff.colossus_smash.up|buff.test_of_might.up
actions.execute+=/skullsplitter,if=rage<40
actions.execute+=/cleave,if=spell_targets.whirlwind>2&dot.deep_wounds.remains<gcd
actions.execute+=/overpower,if=rage<40&buff.martial_prowess.stack<2
actions.execute+=/mortal_strike,if=debuff.executioners_precision.stack=2|dot.deep_wounds.remains<=gcd
actions.execute+=/execute
actions.execute+=/shockwave,if=talent.sonic_boom
actions.execute+=/overpower
actions.execute+=/bladestorm

actions.hac+=/execute,if=buff.juggernaut.up&buff.juggernaut.remains<gcd
actions.hac+=/thunder_clap,if=active_enemies>2&talent.thunder_clap&talent.blood_and_thunder&talent.rend&dot.rend.remains<=dot.rend.duration*0.3
actions.hac+=/sweeping_strikes,if=active_enemies>=2&(cooldown.bladestorm.remains>15|!talent.bladestorm)
actions.hac+=/rend,if=active_enemies=1&remains<=gcd&(target.health.pct>20|talent.massacre&target.health.pct>35)|talent.tide_of_blood&cooldown.skullsplitter.remains<=gcd&(cooldown.colossus_smash.remains<=gcd|debuff.colossus_smash.up)&dot.rend.remains<dot.rend.duration*0.85
actions.hac+=/avatar,if=raid_event.adds.in>15|talent.blademasters_torment&active_enemies>1|target.time_to_die<20
actions.hac+=/warbreaker,if=raid_event.adds.in>22|active_enemies>1
actions.hac+=/colossus_smash,cycle_targets=1,if=(target.health.pct<20|talent.massacre&target.health.pct<35)
actions.hac+=/colossus_smash
actions.hac+=/thunderous_roar,if=(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)&raid_event.adds.in>15|active_enemies>1&dot.deep_wounds.remains
actions.hac+=/spear_of_bastion,if=(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)&raid_event.adds.in>15
actions.hac+=/bladestorm,if=talent.unhinged&(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)
actions.hac+=/bladestorm,if=active_enemies>1&(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)&raid_event.adds.in>30|active_enemies>1&dot.deep_wounds.remains
actions.hac+=/cleave,if=active_enemies>2|!talent.battlelord&buff.merciless_bonegrinder.up&cooldown.mortal_strike.remains>gcd
actions.hac+=/whirlwind,if=active_enemies>2|talent.storm_of_swords&(buff.merciless_bonegrinder.up|buff.hurricane.up)
actions.hac+=/skullsplitter,if=rage<40|talent.tide_of_blood&dot.rend.remains&(buff.sweeping_strikes.up&active_enemies>=2|debuff.colossus_smash.up|buff.test_of_might.up)
actions.hac+=/mortal_strike,if=buff.sweeping_strikes.up&buff.crushing_advance.stack=3,if=set_bonus.tier30_4pc
actions.hac+=/overpower,if=buff.sweeping_strikes.up&talent.dreadnaught
actions.hac+=/mortal_strike,cycle_targets=1,if=debuff.executioners_precision.stack=2|dot.deep_wounds.remains<=gcd|talent.dreadnaught&talent.battlelord&active_enemies<=2
actions.hac+=/execute,cycle_targets=1,if=buff.sudden_death.react|active_enemies<=2&(target.health.pct<20|talent.massacre&target.health.pct<35)|buff.sweeping_strikes.up
actions.hac+=/thunderous_roar,if=raid_event.adds.in>15
actions.hac+=/shockwave,if=active_enemies>2&talent.sonic_boom
actions.hac+=/overpower,if=active_enemies=1&(charges=2&!talent.battlelord&(debuff.colossus_smash.down|rage.pct<25)|talent.battlelord)
actions.hac+=/slam,if=active_enemies=1&!talent.battlelord&rage.pct>70
actions.hac+=/overpower,if=charges=2&(!talent.test_of_might|talent.test_of_might&debuff.colossus_smash.down|talent.battlelord)|rage<70
actions.hac+=/thunder_clap,if=active_enemies>2
actions.hac+=/mortal_strike
actions.hac+=/rend,if=active_enemies=1&dot.rend.remains<duration*0.3
actions.hac+=/whirlwind,if=talent.storm_of_swords|talent.fervor_of_battle&active_enemies>1
actions.hac+=/cleave,if=!talent.crushing_force
actions.hac+=/ignore_pain,if=talent.battlelord&talent.anger_management&rage>30&(target.health.pct>20|talent.massacre&target.health.pct>35)
actions.hac+=/slam,if=talent.crushing_force&rage>30&(talent.fervor_of_battle&active_enemies=1|!talent.fervor_of_battle)
actions.hac+=/shockwave,if=talent.sonic_boom
actions.hac+=/bladestorm,if=raid_event.adds.in>30
actions.hac+=/wrecking_throw

actions.single_target+=/sweeping_strikes,if=spell_targets.whirlwind>1
actions.single_target+=/mortal_strike
actions.single_target+=/rend,if=remains<=gcd|talent.tide_of_blood&cooldown.skullsplitter.remains<=gcd&(cooldown.colossus_smash.remains<=gcd|debuff.colossus_smash.up)&dot.rend.remains<dot.rend.duration*0.85
actions.single_target+=/avatar,if=talent.warlords_torment&rage.pct<33&(cooldown.colossus_smash.ready|debuff.colossus_smash.up|buff.test_of_might.up)|!talent.warlords_torment&(cooldown.colossus_smash.ready|debuff.colossus_smash.up)
actions.single_target+=/spear_of_bastion,if=cooldown.colossus_smash.remains<=gcd|cooldown.warbreaker.remains<=gcd
actions.single_target+=/warbreaker
actions.single_target+=/colossus_smash
actions.single_target+=/thunderous_roar,if=buff.test_of_might.up|talent.test_of_might&debuff.colossus_smash.up&rage.pct<33|!talent.test_of_might&debuff.colossus_smash.up
actions.single_target+=/bladestorm,if=talent.hurricane&(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)|talent.unhinged&(buff.test_of_might.up|!talent.test_of_might&debuff.colossus_smash.up)
actions.single_target+=/skullsplitter,if=talent.tide_of_blood&dot.rend.remains&(debuff.colossus_smash.up|cooldown.colossus_smash.remains>gcd*4&buff.test_of_might.up|!talent.test_of_might&cooldown.colossus_smash.remains>gcd*4)|rage<30
actions.single_target+=/execute,if=buff.sudden_death.react
actions.single_target+=/shockwave,if=talent.sonic_boom.enabled
actions.single_target+=/ignore_pain,if=talent.anger_management|talent.test_of_might&debuff.colossus_smash.up
actions.single_target+=/whirlwind,if=talent.storm_of_swords&talent.battlelord&rage.pct>80&debuff.colossus_smash.up
actions.single_target+=/overpower,if=charges=2&!talent.battlelord&(debuff.colossus_smash.down|rage.pct<25)|talent.battlelord
actions.single_target+=/whirlwind,if=talent.storm_of_swords|talent.fervor_of_battle&active_enemies>1
actions.single_target+=/thunder_clap,if=talent.battlelord&talent.blood_and_thunder
actions.single_target+=/overpower,if=debuff.colossus_smash.down&rage.pct<50&!talent.battlelord|rage.pct<25
actions.single_target+=/whirlwind,if=buff.merciless_bonegrinder.up
actions.single_target+=/cleave,if=set_bonus.tier29_2pc&!talent.crushing_force
actions.single_target+=/slam,if=rage>30&(!talent.fervor_of_battle|talent.fervor_of_battle&active_enemies=1)
actions.single_target+=/bladestorm
actions.single_target+=/arcane_torrent
actions.single_target+=/cleave
actions.single_target+=/wrecking_throw
actions.single_target+=/rend,if=remains<duration*0.3